In the Old Cathedral, the saintess raises a chalice at the altar as the congregation weeps for the Hero of Sienan. What is the name gracing their lips?
*input_text fname
*set nameset true

In a small town in the Parami east, the innkeep's lips tremble as she plants flowers around a pair of graves. Whose names are etched onto the headstones?
*choice
    #The innkeep's two sons.
        *set they "he"
        *set their "his"
        *set them "him"
        *set themselves "himself"
        *set theirs "his"
        *set pronvar 1
        *set plural false
        *set gender "male"
    #A daughter, and a son.
        *set they "she"
        *set their "her"
        *set them "her"
        *set themselves "herself"
        *set theirs "hers"
        *set pronvar 2
        *set plural false
        *set gender "female"
    #A son, and someone who eschewed such labels.
        *set they "they"
        *set their "their"
        *set them "them"
        *set themselves "themselves"
        *set theirs "theirs"
        *set pronvar 3
        *set plural true
        *set gender "nonbinary"

*set genderset true
Beside her shaking form stands another, a lone visitor come to pay their respects. What words have they for the innkeep?
*choice
    #"Sorry Sofiya can't make it, Aunt Bess. She hasn't stopped crying since she heard the news."
        *set charisma true
    #"$!{they} always @{plural were|was} a kind soul, Bess. I still have the books ${they} gave me when ${they} left."
        *set learning true
    #"It's a shame...${they} @{plural were|was} a damn good informant. My very best."
        *set intrigue true
*page_break
The stage is set, and the pyre lit. This is the story of mourners, the ones who were left behind.
*page_break
"I'm really sorry about this, Aunt Bess."

Kadan bows his head deeply, the rucksack in his arms jostling from the motion. The innkeep heaves a long sigh as she watches the boy, all freckles and tangled brown hair, and wonders what destiny awaits him in the big city. Fate hasn't been kind to @{pronvar boys|young'uns|young'uns} who'd supped from her bowl—she can only hope Kadan will be the one to break the curse.

"Never you mind that. I've been running this inn for thirty years. I'll be damned if it shuts down just 'cause I lost an errand boy." Kadan's head only seemed to sink deeper, so she grabs him by the shoulders and pulls him up. "Don't insult me, brat. I'll be just fine without you, so don't you go worryin' about this ratty old inn."

The brat in question huffs a shaky laugh, wipes a tear from the corner of his eye. "I would've stayed here if I could, Aunt Bess. You know that, right?"

"Aye, and then your mother will have shaved your head for turning down a job with the barony," she says curtly. "You've always had big dreams, Kadan. I'll be damned if this inn ties you down."
*page_break
The letter had arrived almost out of the blue, some three or four weeks ago. Stablehand for the local baron—decent pay to start with, and with Kadan's work ethic he could probably end up a butler in ten or so years. Servants are never paid overmuch, even in noble holdings, but certainly Bellgrove Inn couldn't even hope to compare.

It's a blessing of no small measure, but for the request to arrive [i]here[/i], in the middle of nowhere, asking for her errand boy by name…?

The dread that coils in her stomach is cold, familiar. She had felt it when ${fname} left for Sienan. But she had paid it no mind—and so on walked the mage, to the side of a prince who would later execute ${them}.

${fname} still haunts her dreams, at times, joins her son as they beg and jeer and blame. She wonders privately if Kadan will be next. Another child who'd saved her life, and one she'd fail to save in turn.

"Aunt Bess?"

"Mm," she mumbles, shaking herself out of the dark reverie. She hands him a pouch of coins, then, all that's left of what her husband left behind. She'd planned to use it for the inn, to replace the creaking floorboards and get proper tables for the tavern. But there's no point now—not when there's no one to leave the inn to anymore. "For the road."

Kadan goes wide-eyed at the offer, nearly drops his rucksack as he backs away. "Aunt Bess, I couldn't—"

"Yes you can," she says, stuffing the pouch into his hand. "I won't take no for an answer. Either you take it or the river will."

The boy is silent for a while, withering under her glare. And then with a purse of his lips he slips the pouch into his travel sack. "Thank you," he says at length.

"Mm. You go safely now."

His nod is firm, though his gaze refuses to meet her own. "Aye, Aunt Bess. Farewell."
*page_break
The wind is gentle tonight, soft breaths that set the leaves to swaying in the night. The kind of tranquil weather that helps to chase away the nightmares. She should be in bed by now, savoring what little sleep she can before going on her first restock run in ten years.

Instead, she's standing in her doorway, accosted by a bright-eyed young man shivering in the autumn cold.

"Hello." The smile he's giving her is hesitant, but his green eyes are bright and alert. "Is this the Bellgrove Inn?"

The sign is as tall as he is—she knows damn well he couldn't have missed it. "What do you want?"

"I'm sorry to bother you," he tries, looking at his shoes. Muddy and frayed, signs of a long journey. "Wynne down at the bakery told me that you might be looking for an errand boy? I—I could do that, ma'am, if you'll have me. I have experience."

The innkeep crosses her arms. "Just who are you?"

"I'm called Saine," he says, smiling, evidently relieved that she even gave him the time of day. "I was an errand boy, too, up north in Bornerow. I know the work, ma'am, and I'm a hard worker. I promise."

The timing is convenient, she notes to herself. Not three days since Kadan left Leaf End, and along comes his replacement, a desperate young man who'd do anything for shelter and a warm meal. She always was mistrustful by nature—she had to be, when her husband had gotten conned out of his savings every other month—and every single one of her instincts are telling her to shut the door in the boy's face.

But she knew grief like an old friend, found it creased into the lines of her reflection, remembers it in the eyes of a @{pronvar boy|girl|child} she considered her own, all those years ago.

And for all that the boy before her is smiling, she knows. That under all the layers of forced cheer, he, like her, is a creature of sorrow.

"Take tomorrow to rest," she says. "I'll put you to work the morning after."

The boy grins wide at her, his features crinkling with mirth and youthful cheer. He takes her hand in gratitude, bright green eyes compelling her to put stock in his tale. That he is a happy, well-adjusted boy, for whom a job wiping tables and pouring ale in a backwater town is a dream come true.

She takes a breath and leads him inside. If he is half as fine an errand boy as he is an actor, she will have been better off for losing Kadan.

(Besides…she is old. Dying of grief. There will be tables to serve and errands to run, dark thoughts to chase away when all she has for company are a pair of silent graves.)

The boy is unrelenting in his gratitude as he trails behind her. "I don't know what I would've done. Thank you for taking me in, ma'am."

"Aunt Bess."

"Pardon?"

(Strange diction for a war orphan, she does not say.)

"That's Aunt Bess to you now. Everyone 'round here calls me that."
*page_break
The young man lives up to his promises, almost to a frightening degree.

He gets up in the early hours of the morning, is out the door before she can shake the sleep out of her eyes. He is done with groceries before the sun is properly up, does her books for her, works the tavern floor as if he'd been a barmaid for years. It is not long before the innkeep finds that she is wanting for work—anything she wants done, the boy has beaten her to the punch.

She properly draws the line when he peers inside the kitchen, eyeing her produce with carefully mild interest. The offer is on the tip of his tongue, she knows, but she does not let him say it—instead she dumps him in the front door, shoves a pouch of coins in his hands, and tells him to not come back until the sun has set.

(He accepts the coins gratefully, but for all that the boy is keeping the books she can tell when there is more money to her name than there ought to be.)

She tells him one day that he should put his feet up, that she doesn't fancy fishing him out from the snow once he's collapsed from overwork. He flashes her a lopsided grin and thanks her for looking out for him. Promises her he'll take it easy.

This time, he does not keep his word.
*page_break
"Brat, where did you put the ginger ale?"

"It should be out back, near the firewood."

"Drag it to the kitchen next time, will you? Saves an old woman some trouble."

"Alright, Auntie."

"[i]Auntie?[/i]"

The boy frowns. "You don't like it?"

And she thought [i]${fname}[/i] had mastered the puppy-dog eyes. "…Call me what you want, brat."

His grin is near-blinding. "Yes, Auntie."
*page_break
The innkeep wakes with a sudden jerk, hair matted with cold sweat as she catches her breath. The nightmare fades into the back of her mind—it's the pyre, always the pyre, ${fname}'s face twisting in agony as tongues of flame engulf ${their} shaking form whole—

She shakes the image off, the bed underneath creaking from the motion. [i]@{pronvar He's|She's|They're} in a better place now,[/i] she insists to herself. She has never been a woman of the faith, but anywhere must have been better than the hellscape
${they} went through, here in Param. $!{they} had sweated and bled for a cause that killed ${them}, for a king that showed ${them} neither faith nor mercy. Whatever waited beyond the veil must be an improvement. Of this, at least, she is certain.

She forces herself on her feet and hobbles out of the room. Her aged joints are screaming in protest—they've been acting up lately, and without ${fname}'s enchantments to stymie the pain she's had to grit her teeth through it—but for all that the pyre was a mere dream there is ash in her throat that only good ale could wash down. And so she goes.

The innkeep stills as she passes by the window downstairs. An unfamiliar voice—disquieting when she knows nearly everyone in Leaf End. She creeps along the walls, as silently as she can, and presses her ears to the windowsill.

"—please, you can't continue to blame him," the stranger says, desperately.

"But I can." The innkeep's eyes widen at the familiar voice—her new hire, though the steel in his tone is worlds apart from the bright facade he masterfully wears around her. "Tell my brother that if his lackeys drag me back against my will, I'll be leaving again. At the first opportunity I get. And this time he [i]won't[/i] find me again."

The stranger lets out something like a whine. "He'd been refusing his meals for days, when I left. Hasn't he—hasn't he suffered enough? Please, you have to reconsider, Your High—"

"Silence," the errand boy hisses, and she could feel the chill of his venom even through the glass panes. "Don't make me repeat myself. [i]Leave, Gael[/i]."

A sniff, a grumble too low for her to hear, and the stranger departs into the night. The innkeep pulls herself from the wall, then, quickly ducks into the kitchen and presses herself against the door. She couldn't hear the scrape of his feet climbing up the stairs—she waits for twenty minutes, thirty, and when she peers out again the room is eerily silent, her errand boy nowhere to be seen.

He's a liar, she thinks lucidly. He has family to turn to—family that's [i]looking for him[/i], and yet here he is breaking his back, working for a run-down inn in Param's impoverished east. A boy whose myriad masks slip on with a practiced ease, whose steps are as silent as the night.

Just who is it that she had welcomed into her home?

The innkeep fetches her strongest liquor from the uppermost shelf, and drinks until the sun comes up.
*page_break
"Auntie, we don't have enough flour for the meat pies."

"That's a shame. The grocer is closed too, at this time of day…I reckon Wynne down at the bakery has some she could spare, though."

"Oh, that's great! I've been helping her out with inventory lately—if I ask nicely, I'm sure she'll show some mercy for little old Saine."

"If that's even your name."

"What was that, Auntie?"

"Nothing. Go on then, the flour ain't gonna fetch itself."
*page_break
*if (charisma)
    "I'm glad you've been doing better, Aunt Bess."

    Sofiya leans over the counter as she helps herself to another glass of ale. The innkeep would normally chide her for day drinking, but it would've made her a hypocrite when she's on her third glass herself.

    The dancer had stopped by the inn periodically, after news of ${fname}'s execution broke. She'd have her bard partner in tow, normally, but the boy's been busy this season—something about a new role in the theater, out in Calinger. She couldn't bring herself to mind, really. For all that Rean is a good kid he was too much of a skirt-chaser. Always some girl crying from a broken heart when he skips town not a week after he arrived.

    Sofiya, meanwhile, mostly keeps to herself. She would rather talk of ${fname} and ${their} time in Calinger, about the missions ${they} went on and the stories still told. She would often hesitate to speak of the king, but a stern gaze and another glass of liquid courage always did wonders to loosen her lips.

    "Glad I could look put together for you, brat," she grunts. "I've had a good amount of help 'round here."

    "That's good, Aunt Bess," the younger sayls. "I was really worried when I heard Kadan had skipped town. Nearly signed up for the position myself."

    "Hah! None of you have any faith in me," the innkeep chides, sighing as she downs her drink. There's no denying that the boy has been immensely helpful, but thoughts of that night haunts her still, even now. Just what was it that he isn't telling her?

    A knock from the front door alerts her to a visitor, and when she looks up she finds that familiar shock of brown hair just beyond the jambs. "Ah, but here he comes now."

    The boy dusts himself off before he walks in, a smattering of white powder painting the ground white around him. "I put the flour out front, Auntie. Just let me know when you want it moved inside."

    The innkeep nods at his words. "Alright. Head upstairs and take a bath, boy. I've had the water ready for you."

    "Thanks, Auntie," he says, before his gaze lands upon the innkeep's companion. "Oh, we have a guest. I don't think we've met before?"

    The dancer is silent, for a long while, but a nudge on the shoulder and she all but reanimates. "No, I don't think we have," she says finally. "I'm…Sofi, an old friend of your auntie here. I'm just passing through town, so you wouldn't have seen me before."

    "Ah, that makes sense," he says agreeably. "Nice to meet you, Sofi. I'm Saine, the inn's new errand boy. If you ever need anything while you're staying here…"

    "I'll call on you," she finishes for him. Sofiya's smile is oddly strained—she had always been the friendly sort, if a little reserved without Rean around. It's strange to see her so on edge, especially when the errand boy has all but charmed the rest of Leaf End. "Thank you for the offer, Saine."

    He nods happily and goes on his way. The innkeep lowers her voice to a whisper as she leans towards the girl.

    "Something the matter, Sofiya?"

    The younger doesn't immediately respond, her eyes still trailing after the errand boy as he bounds up the stairs. "Aunt Bess," she says at length, a vague sense of horror percolating her tone.
    
    "Why…why have you got the prince of Param working as your errand boy?"
*elseif (learning)
    "I'm glad you've been doing better, Bess."

    Nellyn leans over the counter and pats her head lightly. For a moment the innkeep is transported to a time over forty years ago, when the elderly shopkeep was a blushing bride and she her bridesmaid. It was a happy time, radiant; they'd speak often of giggling children and full homes, of growing old together surrounded by laughter.

    Of course, time has been cruel to them both. Their husbands had passed not a year apart from one another, and where the innkeep had lost two children Nellyn could never bear one. She had instead spent her forties working for a marquess, after her husband had passed. As the innkeep understands it, she was a scholar of no small standing in Sienan circles—her old sponsors still calls her out of Leaf End, every now and again.

    "Glad I could look put together for you, Nellyn," she grunts. "I've had a good amount of help 'round here."

    "So I've heard," the older giggles. "They love him down in the market, you know. Always helping out the old folks out with moving boxes, keeping track of goods. To hear Wynne tell it, Gabe looks about ready to adopt him."

    "Stealing from a grieving widow? That sounds just like him," the innkeep says, sighing as she wipes down the plates. There's no denying that the boy has been immensely helpful, but thoughts of that night haunts her still, even now. Just what was it that he isn't telling her?

    A knock from the front door alerts her to a visitor, and when she looks up she finds that familiar shock of brown hair just beyond the jambs. "Ah, but here he comes now."

    The boy dusts himself off before he walks in, a smattering of white powder painting the ground white around him. "I put the flour out front, Auntie. Just let me know when you want it moved inside."

    The innkeep nods at his words. "Alright. Head upstairs and take a bath, boy. I've had the water ready for you."

    "Thanks, Auntie," he says, before his gaze lands upon the innkeep's companion. "Oh, we have a guest. I don't think we've met before?"

    The shopkeep is silent, for a long while, but a nudge on the shoulder and she all but reanimates. "No, I don't think we have, my boy," she says finally. "I'm Old Nellyn, I run a bookshop down by the market."

    "Ah, nice to meet you. I'm Saine, the inn's new errand boy. If you ever need any help…"

    "I'll call on you," she finishes for him. Nellyn's smile is oddly strained—she had always been the friendly sort, with a penchant for stuffing young'uns with her homemade cookies. It's strange to see her so on edge, especially when she half-expects the shopkeep would smother the boy. "Thank you for the offer, lad."

    He nods happily and goes on his way. The innkeep lowers her voice to a whisper as she leans towards her friend.

    "Something the matter, Nellyn?"

    The older doesn't immediately respond, her eyes still trailing after the errand boy as he bounds up the stairs. "Bess," she says at length, a vague sense of horror percolating her tone.
    
    "Care to tell me why you've got the prince of Param working as your errand boy?"
*else
    "You seem to be doing better these days, innkeep."

    Deacon Thomas leans over the counter as he helps himself to another glass of ale. The innkeep would normally chide the man for day drinking, but it would've made her a hypocrite when she's on her third glass herself.

    The…[i]informant[/i] had stopped by the inn periodically, after news of ${fname}'s execution broke. Something about a favor the mage had extracted from him, just in case ${they} didn't make it to Sienan. To hear him tell it, he'd expected to have to pull the inn out of bankruptcy, and was pleasantly surprised to find that it's business as usual for Bellgrove.

    The Deacon, she understands, is a very busy man. One with influence to throw around, too—reading between the lines of ${fname}'s tales, she knew the man's got tendrils even among the nobility, out in Sienan. That he'd show up to her inn at all sends an uncharacteristic chill down her spine. She privately wonders what ${fname} had done in his service, to have him under ${their} thumb even in death.

    "Glad I look put together for you, Deacon," she grunts. "I've had a good amount of help 'round here."

    "So I've heard. Congratulations on the new hire," the man says curtly. "It was an odd thing that your Kadan was scouted out for the barony. There was something at work there, no doubt, but I haven't the resources to spare investigating. Bigger fish to fry than our good Baron, I'm afraid."

    "I figured as much. But look into it when you get the chance, will you?"
    
    "A bleeding heart? How novel. Why worry about him when you've got a better one under your wings?"
    
    "I should've known better than to ask you," the innkeep says, sighing as she downs her drink. There's no denying that the boy has been immensely helpful, but thoughts of that night haunts her still, even now. Just what was it that the boy isn't telling her?

    A knock from the front door alerts her to a visitor, and when she looks up she finds that familiar shock of brown hair just beyond the jambs. "Ah, but here he comes now."

    The boy dusts himself off before he walks in, a smattering of white powder painting the ground white around him. "I put the flour out front, Auntie. Just let me know when you want it moved inside."

    The innkeep nods at his words. "Alright. Head upstairs and take a bath, boy. I've had the water ready for you."

    "Thanks, Auntie," he says, before his gaze lands upon the innkeep's companion. "Oh, we have a guest. I don't think we've met before?"

    The netter is silent, for a long while, but a nudge on the shoulder and his lips curl into a businesslike smile. "No, I don't think we have," he says finally. "I'm Thomas, an old friend of your auntie here. I'm just passing through town, so you wouldn't have seen me before."

    "Ah, that makes sense," he says agreeably. "Nice to meet you, Mister Thomas. I'm Saine, the inn's new errand boy. If you ever need anything while you're staying here…"

    "I'll call on you," he finishes for him. The Deacon's smile is strained—odd, when ${fname} had always spoken of him as the sturdy, unflappable sort. It's unnerving to see him on edge, especially when the trigger is her very own errand boy. "Thank you for the offer, boy."

    He nods happily and goes on his way. The innkeep lowers her voice to a whisper as she leans towards the informant.

    "Something the matter, Deacon?"

    The man doesn't immediately respond, his eyes still trailing after the errand boy as he bounds up the stairs. "Innkeep," he says at last, carefully neutral.
    
    "Are you aware that your errand boy is the prince of Param?"
*page_break
"Will you tell me about them?"

"Who?"

"Your @{pronvar sons|children|children}."

"…No."

"I see. I'm sorry for asking."

"Don't be. It's just—some things feel wrong to share. With strangers."

The boy is silent for a long while, and when he speaks again there's a tremble to his voice. "Yeah. Yeah, I understand, Auntie."
*page_break
That night, she decides to finally confront him. There is little point in dancing around the subject, when the prince's identity has been laid bare before her.
*if (charisma)
    Sofiya had spoken of the boy's time in Calinger, when he was known as the Shadow for his silent steps and skill with a dagger. His enemies never saw him coming, would only wind up dead with their innards laid bare on the ground.
*elseif (learning)
    Nellyn had spoken of the boy's efforts during the war, when he was known as the Sun King's shadow for his silent steps and skill with a dagger. His enemies never saw him coming, would only wind up dead with their innards laid bare on the ground.
*else
    The Deacon had spoken of the boy's efforts during the war, when he was known as the Sun King's shadow for his silent steps and skill with a dagger. His enemies never saw him coming, would only wind up dead with their innards laid bare on the ground.

Which is to say—if the boy had some nefarious purpose to his stay—[i]if he wanted her dead[/i]—he would have killed her already. She's a deep sleeper, even with the nightmares; it would've been exceedingly simple work, and no one would connect the death of a rural inkeep to a prince. So she knows he's here for something else—for [i]${fname}[/i].

His guard is slipping more and more these days. He prods gently whenever she lets ${their} name slip in conversation, frequents all the places ${they}'d loved, has his eyes linger on ${their} headstone when he thinks she isn't looking. She had finally thrown him a bone, today, talked about the bandits that took her son's life and the mage who had given her back her peace. He had listened intently throughout, his expression expertly blank—an admirable effort, though the tremble of his lips betrayed much of his inner turmoil.

He retreats to his chambers early, that night, before her questions could begin in earnest.

She finds it difficult to mind. The muffled sobs she hears as she passes by his door tells her everything she needs to know.
*page_break
The boy rises bright and early, the next morning. He complains of a dinner missed and raids the kitchen shelves. The innkeep is hawk-eyed as she watches him.

"Had a good sleep?"

His eyes crinkle when he grins. "The best."

There are a million words she could say, she realizes—assurances, accusations, demands. But she could spot the strained set to his cheery smile, powder under his eyes where the puffiness ought to be.

So instead she meets his hunger with a grunt, pours him a bowl of soup, and lets the gentle charade continue.
*page_break
"Oi. Who said you could touch the ale?"

The innkeep crosses her arms as she watches her errand boy, high-flushed and slumped over the table. She had never known him as one to imbibe. When she heard no response knocking on his bedroom door, she half-expected him to be taking inventory or chopping firewood—tasks he'd usually reserve for dawn. He always had been helpful to a fault—almost as if he had something to make up for.

Yet here he is, drunk out of his mind at an hour past midnight.

"Sorry, Auntie," he drawls, his head lolling on the wooden surface. "I only…had one glass."

She considers the generous splattering of amber liquid on the wooden table, the soak of his clothes. A fiction, clearly, but one she lets hang in the air. "You should know better than to drink past your limits."

The boy groans at the reprimand. "Ngh…I didn't know," he slurs. "M'first time."

"Survived this long without the devil's liquid, have you? I'm envious, brat. Some nights they're all what get me through."

The boy's laugh is dry, mirthless. "I don't know…why they said this would make it better. M'not getting better, Auntie. M'not [i]forgetting[/i]."

She takes a seat opposite of him, then, brushes aside the tangle of brown hair on his forehead. His eyes are foggy under the ale's influence, and she realizes with some guilt that this is the first time the boy's let his guard down since he arrived at her inn. Before her is the prince of Param, younger brother of the king who had executed her @{pronvar son|daughter|child}.

And for all that it gives her no pleasure to interrogate him when he is pliant, not in possession of his faculties—she needs to know. Whether what is plaguing this boy is grief over the loss of her @{pronvar son|daughter|child}—or
guilt that he had endorsed ${their} burning.

"And what is it you'd rather forget, brat?"

"My failure."

"Tell me."

The boy's words spill out in a jumbled mess, then. He never mentions ${fname} by name, but he might as well have; he spoke of a mage who had saved a whole kingdom, put to the sword by a king who did not deserve ${their} devotion. Of a desperate, ill-fated escape plan foiled by his own lack of foresight.

The innkeep listens to the drunken tale, for as long as she could. But when the boy spoke of ${fname} as ${they} burned on the pyre—the cutting terror in ${their} eyes right before ${their} body fell slack—she had to leave him, lest the bile rises from her throat in earnest.

The innkeep leans hard against her bedroom door. It is a while before the tremors would subside. She should be grateful, she knows. That the prince sitting in her inn had been an ally—that he was willing to go against his own brother so that her @{pronvar son|daughter|child} may live.

When she returns, the boy's glass is full once more. Liquid sloshes in the cup as he downs it all in one go. "Ngh," he groans, then, all but slamming his head down once more.

The innkeep moves to his side and drapes a blanket over him. "Don't think I'm not putting you to work tomorrow morning."

"You're so mean."

"Damn right I am. Earn your keep."

The innkeep makes to leave, then, but stills when she feels the boy tugging at her sleeve. "Auntie," he mumbles, head still pressed firmly onto the wooden table. "Does it…ever get easier?"

She ponders the question, for a while. Certainly her grief has changed from the aching, bone-chilling horror she felt when the news was fresh, when Kadan had to run the inn alone because she could not move from her chambers. But easier?

Her grief is a shapeshifter, she realizes then—it is a blade in her chest, some days, or a persistent ringing in her skull. But it is not [i]better[/i], even now that she no longer screams her throat raw. How does it matter, when in the end she feels like drowning all the same?

"Quieter," she finally says, hesitant. "Less…constant."

The boy is silent as he notes her non-answer. "But not easier."

"No," she replies. "Never that."
*page_break
"What @{plural were|was} ${they} like?"

"Sorry, Auntie?"

"${fname}," she says, and the boy drops the plate he's wiping. A shard lands itself by her feet, and the innkeep finds that she could not look anywhere else. "When ${they} traveled with you…I want to know what ${they} @{plural were|was} like."

"You knew."

"Mm."

"How long?"

"You should keep away from alcohol, boy, if you know what's good for you."

"[i]Damn it.[/i]"

"So will you tell me?"

"You're not…mad? You're not kicking me out?"

"You tried your best. It's all anyone could ask for."

"But I failed."

"So make up for it. Tell me all about ${them}. The years—the years I missed out on."

Wistfully, tearfully, he does.

And she listens to him all night.
*page_break
The boy leaves her at the turn of the year, speaking of a brother he worries for, despite it all. The flash of anger she felt had passed as quickly as it came; were the positions reversed—that the king burned while ${fname} played executioner—she would have done the same.

She finds a box of gold coins on her bedside that night, ascribed by the boy's note as fortune ${fname} had left behind. Gently folded in the corner is a patch of dirty linen, smaller than her palm and charred at its edges. The only thing left behind when the pyre was doused, when the mage was naught but ashes washed away from Sienan Square.

She plants it by the headstone when the sun comes up. There were so many things left unsaid, the day ${fname} left for Sienan. She waited for the day ${they}'d come back and visit her once more, when the air was clear and their hearts unburdened. Instead she'd heard the crier utter ${their} name in horror, speak of the unspeakable crime she knows ${they} could not commit. Even at ${their} worst. Even if ${they} tried.

A piece of linen is no body, she knows. But it is something.

It means more than she can express. Burns her bones with fire she thought she'd long lost. Recalls memories of a @{pronvar boy|girl|child} who'd stood proud and tall,
despite the grief in ${their} eyes, the burden of ${their} blood. Who by all accounts fought tooth and nail to stay alive, spat in the face of the mercy of death.

So she rises and steels herself, casting a defiant glare at the mockingly clear sky.

She will live, despite it all. Twenty, thirty more years—she will live a full life, a happy life, if only so that she'll have plenty to share when her children welcome her home.
*page_break
And Jove help anyone who'd tell her different.
*page_break
This is the end of [i]Errand Boy.[/i] Thank you for playing!
*ending